home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
sh2x
/
sh25.d64
/
listing 23
(
.txt
)
< prev
next >
Wrap
Commodore BASIC
|
1995-03-30
|
1KB
|
51 lines
10 REM PROGRAMM ZUR KONVERTIERUNG
20 REM VON VIER HEXBYTES IN DIE
30 REM FUENF ENTSPRECHENDEN
40 REM GCR-AEQUIVALENTE
50 REM
60 REM
70 REM
80 REM (W) 1985 BY KARSTEN SCHRAMM
90 REM
100 A$="0123456789ABCDEF":DIMG$(15):E$=""
110 G$(0)="01010"
120 G$(1)="01011"
130 G$(2)="10010"
140 G$(3)="10011"
150 G$(4)="01110"
160 G$(5)="01111"
170 G$(6)="10110"
180 G$(7)="10111"
190 G$(8)="01001"
200 G$(9)="11001"
210 G$(10)="11010"
220 G$(11)="11011"
230 G$(12)="01101"
240 G$(13)="11101"
250 G$(14)="11110"
260 G$(15)="10101"
270 PRINT"[147]HEX - GCR - KONVERTIERUNG":PRINT
280 PRINT:PRINT"GEBEN SIE JETZT 4 HEXBYTES EIN":PRINT
290 PRINT"Z.B. ED 34 27 58":INPUT"";H$:GC$=""
300 GOSUB470:FORX=1TO4
310 H1$=MID$(H$,X*2-1,1):H2$=MID$(H$,X*2,1)
320 H1=VAL(H1$):H2=VAL(H2$)
330 IFH1=0ANDH1$<>"0"THENH1=ASC(H1$)-55
340 IFH2=0ANDH2$<>"0"THENH2=ASC(H2$)-55
350 GC$=GC$+G$(H1)+G$(H2)
360 NEXTX
370 FORX=1TO10
380 B=0:B$=MID$(GC$,X*4-3,4)
390 FORY=0TO3
400 IFMID$(B$,Y+1,1)="1"THENB=B+2^(3-Y)
410 NEXTY
420 E$=E$+MID$(A$,B+1,1)
430 IFX/2=INT(X/2)THENE$=E$+" "
440 NEXTX
450 PRINT:PRINT:PRINT"GCR: ";E$
460 END
470 X$="":FORX=1TOLEN(H$)
480 IFMID$(H$,X,1)<>" "THENX$=X$+MID$(H$,X,1)
490 NEXT
500 H$=X$:RETURN